ATR coupler method

If the light is reflected at a metal surface covered with a dielectric medium ( $\epsilon_{pr} > 1$) , e.g. with a BK7 half cylinder(n=1.515 at 633 nm) or SF10 glass(n=1.723 at 643.8 nm),

$$k_x^{pr} = \sqrt{\epsilon_{pr}}\frac{\omega}{c}\sin\theta_{pr} = n_{pr} \frac{\omega}{c}\sin\theta_{pr}$$ (197)

$$k_z^{pr} = \sqrt{\epsilon_{pr}}\frac{\omega}{c}\cos\theta_{pr} = n_{pr} \frac{\omega}{c}\cos\theta_{pr}$$ (198)

図 10: Schematic diagram of ATR coupler

The resonance condition of the light in the prism with the surface plasmon at metal(1)|air(2) interface (Kretschmann-Raether configuration) is

$$k_x^{pr} = k_x^{sp}$$ (199)

$$\sqrt{\epsilon_{pr}}\frac{\omega}{c}\sin\theta_{pr} = \sqrt{\frac{\tilde{\epsilon }_1 \tilde{\epsilon }_2 }{\tilde{\epsilon }_1 + \tilde{\epsilon }_2 }} \left( \frac{\omega}{c} \right)$$ (200)

The refelcted intensity $R$ can be given by Frensel's equations of the prisim$\vert$metal$\vert$air three layer system.

$$r^p_{ik} = \frac{\tilde{n}_k \cos\theta_i - \tilde{n}_i \cos\theta_k } {\til... ... }{ \tilde{n}_i \omega } + \frac{\tilde{n}_i k_{zk}c } { \tilde{n}_k \omega } }$$ (201)

$$= \frac{ \frac{ k_{zi} }{ \tilde{n}_i^2 } - \frac{ k_{zk} } { \tild... ...ilde{\epsilon }_k } { k_{zi}/\tilde{\epsilon }_i + k_{zk}/\tilde{\epsilon }_k }$$ (202)

$$r^p_{ki} = - r^p_{ik}$$ (203)

For transmission

$$t_{ik}^p = \frac{\tilde{n}_i}{\tilde{n}_k} (1 + r_{ik}^p )$$ (204)

$$t_{ki}^p = \frac{\tilde{n}_k}{\tilde{n}_i} (1 + r_{ki}^p ) = \frac{\tilde{n}_k}{\tilde{n}_i} (1 - r_{ik}^p )$$ (205)

$$t_{ik}^p t_{ki}^p = (1 + r_{ik}^p ) (1 - r_{ik}^p )$$ (206)

The total reflection of the three layer model becomes

$$R = \vert r_{{\rm pr}12}^p \vert^2 = \left\vert \frac{r_{{\rm pr}1}^p... ...e^{2ik_{z1}d_1} } {1 + r_{{\rm pr}1}^p r_{12}^p e^{2ik_{z1}d_1} } \right\vert^2$$ (207)

$$r_{ik}^p = \frac{\tilde{n}_k \cos\theta_i - \tilde{n}_i \cos\theta_k } {\til... ...heta_k /\tilde{n}_k } {\cos\theta_i / \tilde{n}_i + \cos\theta_k /\tilde{n}_k }$$ (208)

$$n_{pr} \sin\theta_{pr} = \tilde{n}_1 \sin\theta_1 = \tilde{n}_2 \sin\theta_2$$

$$\tilde{n}_k \cos \theta_k = \tilde{n}_k (1 - \sin^2 \theta_k)^{1/2} = \tilde{n}_k (1 - n_{pr}... ...} /\tilde{n}_k^2 )^{1/2} = (\tilde{n}_k^2 - n_{pr}^2 \sin^2 \theta_{pr} )^{1/2}$$

$$r_{ik}^p = \frac{ (\tilde{\epsilon }_i - n_{pr}^2 \sin^2 \theta_{pr} )^{1/2}... ...\tilde{\epsilon }_k - n_{pr}^2 \sin^2 \theta_{pr} )^{1/2}/\tilde{\epsilon }_k }$$ (209)

$$r_{{\rm pr}1}^p = \frac{ \cos\theta_{pr} /n_{pr} - (\tilde{\epsilon }_1 - n_{pr}^2 ... ...\tilde{\epsilon }_1 - n_{pr}^2 \sin^2 \theta_{pr} )^{1/2}/\tilde{\epsilon }_1 }$$ (210)

The above equation for $R$ can be understood by

$$r_{{\rm pr}12}^p = \frac{r_{{\rm pr}1}^p + r_{12}^p e^{2ik_{z1}d_1} } {1 + r_{{\rm pr}1}^p r_{12}^p e^{2ik_{z1}d_1} }$$ (211)

$$\approx (r_{{\rm pr}1}^p + r_{12}^p e^{2ik_{z1}d_1}) (1 - r_{{\rm pr}1}^p... ...12}^p e^{2ik_{z1}d_1} + (r_{{\rm pr}1}^p)^2 (r_{12}^p)^2 e^{4ik_{z1}d_1} - ....$$

$$= r_{{\rm pr}1}^p + r_{12}^p e^{2ik_{z1}d_1} - (r_{{\rm pr}1}^p)^2 ... ...}^p)^2 e^{4ik_{z1}d_1} + (r_{{\rm pr}1}^p)^3 (r_{12}^p)^2 e^{4ik_{z1}d_1} + ...$$

$$= r_{{\rm pr}1}^p + (1- r_{{\rm pr}1}^p )^2 r_{12}^p e^{2ik_{z1}d_1} + r_{{\rm pr}1}^p [ (r_{{\rm pr}1}^p)^2 - 1] (r_{12}^p)^2 e^{4ik_{z1}d_1} + ...$$

$$= r_{{\rm pr}1}^p + \underbrace{(1 + r_{{\rm pr}1}^p ) r_{12}^p (1 ... ...{\rm pr}1}^p r_{12}^p r_{1{\rm pr}}^p r_{12}^p t_{1{\rm pr}}^p} e^{4ik_{z1}d_1}$$

$$= r_{{\rm pr}1}^p + t_{{\rm pr}1}^p r_{12}^p t_{1{\rm pr}}^p e^{2ik... ...{{\rm pr}1}^p r_{12}^p r_{1{\rm pr}}^p r_{12}^p t_{1{\rm pr}}^p e^{4ik_{z1}d_1}$$ (212)

$${\rm phase \ factor} \ k_{z1}d_1 = k_1 (d_1 \cos \theta_1) \ {\rm is \ optical \ path \ length}.$$ (213)

$$k_{z1}d_1 = k_1 d_1 \cos \theta_1 = \tilde{n}_1 \frac{\omega}{c}d_1 \left( 1 ... ... = \frac{\omega}{c}d_1 (\tilde{\epsilon}_1 - n_{pr}^2 \sin^2\theta_{pr} )^{1/2}$$ (214)

図 11: SPR curve for SF10($n=1.723$)$\vert$gold(50nm, 0.1726 + $i$ 3.4218)$\vert$air($n=1.0$) for He-Ne laser (633 nm).

The FORTRAN programs is

c234567-- spr_angle_3layer.f ---
c     complex calculation
      implicit real*8 (a-h,o-z)

      complex*16 e1,rpr1,r12,rpr12,rpr12c,alpha,ref
      complex*16 aaa,fukso,e2

      c=2.99792458d8
      hbar=6.5822d-16
      pi=acos(-1.0d0)
c     ------ air ----
      e2=dcmplx(1.0d0,0.0d0)
c     ----- SF10 633 nm
      enpr=1.723d0
c     ----- gold 633 nm
      e1n=0.1726d0
      e1k=3.4218d0
      e1r=e1n**2-e1k**2
      e1i=2.0d0*e1n*e1k
      e1=dcmplx(e1r,e1i)
c     ---- gold thickness (m)
      d1=50.0d-9
c
      ramd=633.0d-9
      omega=2.0d0*pi/ramd*c
      fukso=dcmplx(0.0d0,1.0d0)
      write (6,*) ramd,omega,hbar*omega
c     --------- angle scan ----------
      ang0=35.0d0
      ang1=45.0d0
      do i=1, 1001
       theta=(ang0+dble(i-1)/1000.0d0*(ang1-ang0))/180.0d0*pi
       rpr1=(cos(theta)/enpr -
     &       sqrt(e1-enpr**2*sin(theta)**2)/e1)
     &      / (cos(theta)/enpr +
     &      sqrt(e1-enpr**2*sin(theta)**2)/e1)

       r12=( sqrt(e1-enpr**2*sin(theta)**2)/e1 -
     &       sqrt(e2-enpr**2*sin(theta)**2)/e2 )
     &     / ( sqrt(e1-enpr**2*sin(theta)**2)/e1 +
     &         sqrt(e2-enpr**2*sin(theta)**2)/e2 )
       aaa=2.0d0*omega/c*d1*sqrt(e1-enpr**2*sin(theta)**2)
       alpha=aaa*fukso
       rpr12=(rpr1+ r12*exp(alpha))/(1.0d0+rpr1*r12*exp(alpha))
       rpr12c=conjg(rpr12)
       ref=rpr12*rpr12c
       write (6,*) theta/pi*180.0d0,dble(ref)
      enddo
      end

At resonance or $R = 0$ the power of the SPs is lost by internal absorption in the metal. This loss is compesated by the power of the incomig light. Both have to be equal in the steady state.

If the reflectivity $R$ has lowest value, the intensity of the electromagnetic field reaches its maximum in the surface. For 600 nm light the maximum enhancement of the electric field intensity is ca. 200 for silver film (60 nm thickness), 30 for gold film, 40 for aluminium film, and 7 for copper film, respectrively.